IIDX似非プレミアムモデルの自作

#include "HID-Project.h"

const int key[12] = {
  2, 3, 4, 5, 6, 7, 8,  // Key1-Key7
  9,                    // NC
  18, 19, 20, 21        // E1-E4
};
const int TT_R = 0;  // TurnTable Sensor Right
const int TT_L = 1;  // TurnTable Sensor Left
char TT = 0;         // TurnTable Value

const unsigned long LONG_PRESS_TIME = 1000;  // Long press duration (msec)
unsigned long MODE_end_time = 0;             // Long press end time
bool mode_inf = true;                        // Infinitas Mode OR LR2 Mode

const unsigned long TT_DELAY = 133;  // Turntable Duration (msec)
unsigned long TT_end_time = 0;       // Turntable end time

void setup() {
  // Keys Setup
  for (int i = 0; i < 12; i++) {
    pinMode(key[i], INPUT_PULLUP);
  }
  // TT Setup
  pinMode(TT_R, INPUT_PULLUP);
  pinMode(TT_L, INPUT_PULLUP);

  // TT Interrupt Setup
  // 0:pin3 1:pin2 2:pin0 3:pin1 4:pin7
  attachInterrupt(2, TTcount, RISING);  // Call TTcount when Rising 2=pin0=TT_R

  // Sends a clean report to the host. This is important on any Arduino type.
  Gamepad.begin();
}

void loop() {
  // Read Keys
  for (int i = 0; i < 12; i++) {
    if (!digitalRead(key[i])) {
      Gamepad.press(i + 1);
    } else {
      Gamepad.release(i + 1);
    }
  }

  // Set TT value
  if (mode_inf) {
    // Infinitas Mode
    Gamepad.xAxis(TT * 256);  // IIDX value is 8bit, xAxis is 16bit
    Gamepad.yAxis(0);

  } else {
    // LR2 Mode
    Gamepad.xAxis(0);

    if (TT_end_time > millis()) {
      // The opening time has not yet been reached.
      if (TT == 1) {
        Gamepad.yAxis(32767);
      } else if (TT == -1) {
        Gamepad.yAxis(-32768);
      }
    } else {
      // Reset
      Gamepad.yAxis(0);
      TT = 0;
      TT_end_time = 0;
    }
  }

  // Send Gamepad
  Gamepad.write();

  // Mode switch
  if (!digitalRead(key[8]) && !digitalRead(key[9]) && !digitalRead(key[10]) && !digitalRead(key[11])) {
    // E1-E4 are pressed.

    if (MODE_end_time == 0) {
      // Init
      MODE_end_time = millis() + LONG_PRESS_TIME;  // Set end time
    } else if (MODE_end_time < millis()) {
      // End time is exceeded, switch mode
      mode_inf = !mode_inf;
      // Reset end time
      MODE_end_time = 0;
    }
    // Otherwise, pass.
  } else {
    // Keys released
    // Reset end time
    MODE_end_time = 0;
  }
}

void TTcount() {
  if (mode_inf) {
    // Infinitas mode
    if (digitalRead(TT_L)) {
      TT--;
    } else {
      TT++;
    }
  } else {
    // LR2 mode
    if (digitalRead(TT_L)) {
      TT = 1;
    } else {
      TT = -1;
    }
    // Set turntable end time
    TT_end_time = millis() + TT_DELAY;
  }
}